log using q13, text replace

/* Bereavement data */

use brv, clear

list id sex doe dosp dox fail if couple==3
list id sex doe dosp dox fail if couple==4
list id sex doe dosp dox fail if couple==19

stset dox, fail(fail) origin(dob) entry(doe) scale(365.25) id(id) noshow

strate sex, per(1000)

streg sex, dist(exp) nolog

tabstat _t0, by(sex)

stsplit brv, after(time=dosp) at(0)
recode brv -1=0 0=1

list id sex doe dosp dox brv _t0 _t _d fail if couple==3

streg brv, nolog

streg brv if sex==1, nolog
streg brv if sex==2, nolog

gen brv_m=brv*(sex==1)
gen brv_f=brv*(sex==2)
streg sex brv_m brv_f, nolog

/* Split by attained age */
stsplit age, at(70(5)100)
strate age

/* Poisson regression: effect of bereavement controlled for attained age */
xi: streg brv i.age, nolog

/* Poisson regression: effect of bereavement controlled for attained age and sex */
xi: streg sex brv i.age, nolog

/* Poisson regression: effect of bereavement for each gender (controlled for attained age) */
xi: streg sex brv_m brv_f i.age, nolog

/* Cox regression: effect of bereavement controlled for attained age */
stcox brv, nolog

stsgraph, by(brv) noorigin

/* Cox regression: effect of bereavement controlled for attained age and sex */
stcox brv sex, nolog

/* Cox regression: effect of bereavement for each gender (controlled for attained age) */
stcox sex brv_m brv_f, nolog

log close